Re: [PATCH 5/5] autoconf: don't use platform regex if it lacks REG_STARTEND

j6t@kdbg.org· Aug 17, 2010, 12:50 UTC · lore

Ævar Arnfjörð Bjarmason schrieb:

Show 7 quoted lines

> +[#ifdef REG_STARTEND
> +yippeeyeswehaveit
> +#endif
> +]),
> +	[ac_cv_c_excellent_regex=yes],
> +	[ac_cv_c_excellent_regex=yes])
> +])

Do you have REG_STARTEND?

  o Yes
  o Yes

Choose wisely! :)

-- Hannes

Jonathan Nieder· Aug 17, 2010, 21:47 UTC · re: j6t@kdbg.org · lore

[PATCH 5/5 v2] autoconf: don't use platform regex if it lacks REG_STARTEND

If the platform regex cannot match null bytes, we might as well use the glibc version instead.

Cc: René Scharfe <rene.scharfe@lsrfire.ath.cx>
Tested-by: Ævar Arnfjörð Bjarmason <avarab@gmail.com>
Helped-by: Johannes Sixt <j6t@kdbg.org>
Signed-off-by: Jonathan Nieder <jrnieder@gmail.com>
---
j6t@kdbg.org wrote:

Show 15 quoted lines

> Ævar Arnfjörð Bjarmason schrieb:
>> +[#ifdef REG_STARTEND
>> +yippeeyeswehaveit
>> +#endif
>> +]),
>> +	[ac_cv_c_excellent_regex=yes],
>> +	[ac_cv_c_excellent_regex=yes])
>> +])
>
> Do you have REG_STARTEND?
> 
>   o Yes
>   o Yes
> 
> Choose wisely! :)

Good catch. Warning: I only tested the following with glibc. Testing on platforms with missing or ancient regex support would be very welcome.

 config.mak.in |    1 +
 configure.ac  |   21 +++++++++++++++++++++
 2 files changed, 22 insertions(+), 0 deletions(-)

Show changes to 2 files +22 −0

config.mak.in, configure.ac

diff --git a/config.mak.in b/config.mak.in
index b4e65c3..67dbd3b 100644
--- a/config.mak.in
+++ b/config.mak.in
@@ -58,6 +58,7 @@ NO_INET_NTOP=@NO_INET_NTOP@
 NO_INET_PTON=@NO_INET_PTON@
 NO_ICONV=@NO_ICONV@
 OLD_ICONV=@OLD_ICONV@
+NO_REGEX=@NO_REGEX@
 NO_DEFLATE_BOUND=@NO_DEFLATE_BOUND@
 INLINE=@INLINE@
 SOCKLEN_T=@SOCKLEN_T@
diff --git a/configure.ac b/configure.ac
index 5601e8b..ed0561b 100644
--- a/configure.ac
+++ b/configure.ac
@@ -706,6 +706,27 @@ else
 fi
 AC_SUBST(NO_C99_FORMAT)
 #
+# Define NO_REGEX if you have no or inferior regex support in your C library.
+AC_CACHE_CHECK([whether the platform regex can handle null bytes],
+ [ac_cv_c_excellent_regex], [
+AC_EGREP_CPP(yippeeyeswehaveit,
+	AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
+#include <regex.h>
+],
+[#ifdef REG_STARTEND
+yippeeyeswehaveit
+#endif
+]),
+	[ac_cv_c_excellent_regex=yes],
+	[ac_cv_c_excellent_regex=no])
+])
+if test $ac_cv_c_excellent_regex = yes; then
+	NO_REGEX=
+else
+	NO_REGEX=YesPlease
+fi
+AC_SUBST(NO_REGEX)
+#
 # Define FREAD_READS_DIRECTORIES if your are on a system which succeeds
 # when attempting to read from an fopen'ed directory.
 AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory],

-- 
1.7.2.1.544.ga752d.dirty

Ævar Arnfjörð Bjarmason· Aug 18, 2010, 08:49 UTC · re: Jonathan Nieder · lore

Re: [PATCH 5/5 v2] autoconf: don't use platform regex if it lacks REG_STARTEND

On Tue, Aug 17, 2010 at 21:47, Jonathan Nieder <jrnieder@gmail.com> wrote:

> Good catch.  Warning: I only tested the following with glibc.
> Testing on platforms with missing or ancient regex support would
> be very welcome.

I tested it on Solaris (which I should have done in the first place), there it sets NO_REGEX=YesPlease as expected as Solaris doesn't have REG_STARTEND.

patch, 5 partsRe: [PATCH 5/5] autoconf: don't use platform regex if it lacks REG_STARTEND