threads / patch / 16794

patchgit-send-email: handle email address with quoted comma

Subject: [PATCH] git-send-email: handle email address with quoted comma

## tl;dr

6 messages between Dec 19, 2008 and Dec 20, 2008. Diffs are folded; open one to read it.

replies: 5people: 3as markdown or json

Wu Fengguang· Dec 19, 2008, 03:40 UTC · lore
Correctly handle email addresses containing quoted commas, e.g.
	"Zhu, Yi" <yi.zhu@intel.com>, "Li, Shaohua" <shaohua.li@intel.com>
Here the commas inside the double quotes are NOT email separators.
Signed-off-by: Wu Fengguang <fengguang.wu@intel.com>
---
 git-send-email.perl |   13 ++++++++++---
 1 files changed, 10 insertions(+), 3 deletions(-)
Show changes to git-send-email.perl +10 −3
diff --git a/git-send-email.perl b/git-send-email.perl
index 3112f76..d44e99c 100755
--- a/git-send-email.perl
+++ b/git-send-email.perl
@@ -20,6 +20,7 @@ use strict;
 use warnings;
 use Term::ReadLine;
 use Getopt::Long;
+use Text::ParseWords;
 use Data::Dumper;
 use Term::ANSIColor;
 use File::Temp qw/ tempdir /;
@@ -359,6 +360,12 @@ foreach my $entry (@bcclist) {
 	die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 }
 
+sub split_addrs($) {
+	my ($addrs) = @_;
+
+	return &quotewords('\s*,\s*', 1, $addrs);
+}
+
 my %aliases;
 my %parse_alias = (
 	# multiline formats can be supported in the future
@@ -367,7 +374,7 @@ my %parse_alias = (
 			my ($alias, $addr) = ($1, $2);
 			$addr =~ s/#.*$//; # mutt allows # comments
 			 # commas delimit multiple addresses
-			$aliases{$alias} = [ split(/\s*,\s*/, $addr) ];
+			$aliases{$alias} = [ split_addrs($addr) ];
 		}}},
 	mailrc => sub { my $fh = shift; while (<$fh>) {
 		if (/^alias\s+(\S+)\s+(.*)$/) {
@@ -379,7 +386,7 @@ my %parse_alias = (
 			chomp $x;
 		        $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 			$x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
-			$aliases{$1} = [ split(/\s*,\s*/, $2) ];
+			$aliases{$1} = [ split_addrs($2) ];
 		}},
 	gnus => sub { my $fh = shift; while (<$fh>) {
 		if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
@@ -588,7 +595,7 @@ if (!@to) {
 	}
 
 	my $to = $_;
-	push @to, split /,\s*/, $to;
+	push @to, split_addrs($to);
 	$prompting++;
 }
 

-- 
1.6.0.4
Junio C Hamano· Dec 19, 2008, 06:40 UTC · re: Wu Fengguang · lore

Re: [PATCH] git-send-email: handle email address with quoted comma

Wu Fengguang <fengguang.wu@intel.com> writes:
Show 5 quoted lines
> Correctly handle email addresses containing quoted commas, e.g.
>
> 	"Zhu, Yi" <yi.zhu@intel.com>, "Li, Shaohua" <shaohua.li@intel.com>
>
> Here the commas inside the double quotes are NOT email separators.
Thanks.
Show 10 quoted lines
> @@ -359,6 +360,12 @@ foreach my $entry (@bcclist) {
>  	die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
>  }
>  
> +sub split_addrs($) {
> +	my ($addrs) = @_;
> +
> +	return &quotewords('\s*,\s*', 1, $addrs);
> +}
> +

Does it add real value (e.g. type safety, simplified interface to the caller, etc.) to force scalar context to the callers? It has been my experience that use of prototypes (aka "parameter context templates") in Perl programs tend to make the code less readable and more error prone in longer term. I would further say that, even though you do not have any existing caller of split_addrs sub that uses it for more than two values, not using the prototype would be a better way to write this sub in this particular case, because it would allow callers to say [*1*]:

	@addrs = split_addr(@list_of_addr_lines);

It also is a bit funny-looking to invoke &function() (it is Perl4 style, isn't it?)

IOW, wouldn't this be a better alternative?
	sub split_addrs {
        	return quotewords('\s*,\s*', 1, @_);
	}
[Footnote]

*1* This program demonstrates why use of prototype in this case is more confusing than it is worth.

-- >8 -- #!/usr/bin/perl -w

use Text::ParseWords;
sub foo ($) { my ($addrs) = @_; return quotewords('\s*,\s*', 1, $addrs); }
sub bar { return quotewords('\s*,\s*', 1, @_); }
my @addrs = ('Frotz, "Xyzzy, Zork", Nitfol', 'Yomin, Rezrov');
my @addr = ($addrs[0]);
for (foo($addrs[0])) {
	print "foo(\$addrs[0]) <<$_>>\n";
}
for (foo(@addr)) {
	print "foo(\@addr) <<$_>>\n";
}
for (bar($addrs[0])) {
	print "bar(\$addrs[0]) <<$_>>\n";
}
for (bar(@addr)) {
	print "bar(\@addr) <<$_>>\n";
}
-- 8< --

The output from the above (the fourth one is the most interesting) looks like this.

foo($addrs[0]) <<Frotz>> foo($addrs[0]) <<"Xyzzy, Zork">> foo($addrs[0]) <<Nitfol>> foo(@addr) <<1>> bar($addrs[0]) <<Frotz>> bar($addrs[0]) <<"Xyzzy, Zork">> bar($addrs[0]) <<Nitfol>> bar(@addr) <<Frotz>> bar(@addr) <<"Xyzzy, Zork">> bar(@addr) <<Nitfol>>

*2* A more detailed discussion on Perl's "prototypes" is found here:
http://web.archive.org/web/20080210085941/http://library.n0i.net/programming/perl/articles/fm_prototypes/
Wu Fengguang· Dec 19, 2008, 08:10 UTC · re: Junio C Hamano · lore

Re: [PATCH] git-send-email: handle email address with quoted comma

On Fri, Dec 19, 2008 at 08:40:13AM +0200, Junio C Hamano wrote:
Show 40 quoted lines
> Wu Fengguang <fengguang.wu@intel.com> writes:
> 
> > Correctly handle email addresses containing quoted commas, e.g.
> >
> > 	"Zhu, Yi" <yi.zhu@intel.com>, "Li, Shaohua" <shaohua.li@intel.com>
> >
> > Here the commas inside the double quotes are NOT email separators.
> 
> Thanks.
> 
> > @@ -359,6 +360,12 @@ foreach my $entry (@bcclist) {
> >  	die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
> >  }
> >  
> > +sub split_addrs($) {
> > +	my ($addrs) = @_;
> > +
> > +	return &quotewords('\s*,\s*', 1, $addrs);
> > +}
> > +
> 
> Does it add real value (e.g. type safety, simplified interface to the
> caller, etc.) to force scalar context to the callers?  It has been my
> experience that use of prototypes (aka "parameter context templates") in
> Perl programs tend to make the code less readable and more error prone in
> longer term.  I would further say that, even though you do not have any
> existing caller of split_addrs sub that uses it for more than two values,
> not using the prototype would be a better way to write this sub in this
> particular case, because it would allow callers to say [*1*]:
> 
> 	@addrs = split_addr(@list_of_addr_lines);
> 
> It also is a bit funny-looking to invoke &function() (it is Perl4 style,
> isn't it?)
> 
> IOW, wouldn't this be a better alternative?
> 
> 	sub split_addrs {
>         	return quotewords('\s*,\s*', 1, @_);
> 	}
Hi Junio and Matt,

Thank you for the helpful information. The patch is updated and tested according to your comments.

Thanks, Fengguang --- git-send-email: handle email address with quoted comma

Correctly handle email addresses containing quoted commas, e.g.
	"Zhu, Yi" <yi.zhu@intel.com>, "Li, Shaohua" <shaohua.li@intel.com>
Here the commas inside the double quotes are NOT email separators.
Signed-off-by: Wu Fengguang <fengguang.wu@intel.com>
---
 git-send-email.perl |   11 ++++++++---
 1 files changed, 8 insertions(+), 3 deletions(-)
Show changes to git-send-email.perl +8 −3
diff --git a/git-send-email.perl b/git-send-email.perl
index 3112f76..6114401 100755
--- a/git-send-email.perl
+++ b/git-send-email.perl
@@ -20,6 +20,7 @@ use strict;
 use warnings;
 use Term::ReadLine;
 use Getopt::Long;
+use Text::ParseWords;
 use Data::Dumper;
 use Term::ANSIColor;
 use File::Temp qw/ tempdir /;
@@ -359,6 +360,10 @@ foreach my $entry (@bcclist) {
 	die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 }
 
+sub split_addrs {
+	return parse_line('\s*,\s*', 1, @_);
+}
+
 my %aliases;
 my %parse_alias = (
 	# multiline formats can be supported in the future
@@ -367,7 +372,7 @@ my %parse_alias = (
 			my ($alias, $addr) = ($1, $2);
 			$addr =~ s/#.*$//; # mutt allows # comments
 			 # commas delimit multiple addresses
-			$aliases{$alias} = [ split(/\s*,\s*/, $addr) ];
+			$aliases{$alias} = [ split_addrs($addr) ];
 		}}},
 	mailrc => sub { my $fh = shift; while (<$fh>) {
 		if (/^alias\s+(\S+)\s+(.*)$/) {
@@ -379,7 +384,7 @@ my %parse_alias = (
 			chomp $x;
 		        $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 			$x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
-			$aliases{$1} = [ split(/\s*,\s*/, $2) ];
+			$aliases{$1} = [ split_addrs($2) ];
 		}},
 	gnus => sub { my $fh = shift; while (<$fh>) {
 		if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
@@ -588,7 +593,7 @@ if (!@to) {
 	}
 
 	my $to = $_;
-	push @to, split /,\s*/, $to;
+	push @to, split_addrs($to);
 	$prompting++;
 }
 

-- 
1.6.0.4
Matt Kraai· Dec 19, 2008, 16:28 UTC · re: Wu Fengguang · lore

Re: [PATCH] git-send-email: handle email address with quoted comma

Howdy,
Wu Fengguang <fengguang.wu <at> intel.com> writes:
> +sub split_addrs {
> +	return parse_line('\s*,\s*', 1, @_);
> +}
> +

I'm not sure it's still a good idea to use parse_line. It should work OK for now, since split_addrs is only passed one string. If anyone ever tries to pass it a list of strings, however, parse_line will ignore all but the first.

-- 
Matt
Junio C Hamano· Dec 20, 2008, 20:09 UTC · re: Matt Kraai · lore

Re: [PATCH] git-send-email: handle email address with quoted comma

Matt Kraai <kraai@ftbfs.org> writes:
Show 11 quoted lines
> Howdy,
>
> Wu Fengguang <fengguang.wu <at> intel.com> writes:
>> +sub split_addrs {
>> +	return parse_line('\s*,\s*', 1, @_);
>> +}
>> +
>
> I'm not sure it's still a good idea to use parse_line.  It should work OK for
> now, since split_addrs is only passed one string.  If anyone ever tries to pass
> it a list of strings, however, parse_line will ignore all but the first.

Yikes, I should have caught this. As you point out, this is a breakage waiting to happen until somebody restructures the callers. We should futureproof it by using quotewords() instead.

Junio C Hamano· Dec 20, 2008, 06:48 UTC · re: Wu Fengguang · lore

Re: [PATCH] git-send-email: handle email address with quoted comma

Wu Fengguang <fengguang.wu@intel.com> writes:
> Thank you for the helpful information. The patch is updated and tested

Thanks. I'll apply but it would be nice to have an additional test script somewhere in t/t9001-send-email.sh to protect this change from regression by future changes.

← back to recent threads